【ワードマクロ】表の行・列に色付け：コピペで使えるコード

ワードマクロで、表の行・列に色付けするVBAコードをご紹介します。

このページのマクロコードは、コピペで使えます。
ぜひ、お試しください！

表の列に色付け
表の行に色付け（カーソルがある行）
表の行に色付け（任意の行）

表の列に色付け

以下のWordVBAを実行すると、
ワードファイル内にあるすべての表の1列目と最終列に色を塗ります。


Sub 表の特定の列に色を付ける()
    
  Dim i As Long
  Dim j As Long
  Dim TblCnt As Long
  Dim TblColumnCnt As Long
  Dim CellCnt As Long
    
  'ファイル内にある表をカウント
  TblCnt = ActiveDocument.Tables.Count
    
  '全ての表をループ
  For i = 1 To TblCnt
    
     With ActiveDocument.Tables(i)
      
        TblColumnCnt = .Columns.Count
        CellCnt = .Range.Cells.Count
            
        For j = 1 To CellCnt
               
           '表の1列目の背景色をグレーに変更
           If .Range.Cells.Item(j).ColumnIndex = 1 Then
              .Range.Cells.Item(j).Range.Cells. _
              Shading.BackgroundPatternColorIndex = wdGray25
           End If
                
           '表の最終列の背景色を黄色に変更
           If .Range.Cells.Item(j).ColumnIndex = TblColumnCnt Then
              .Range.Cells.Item(j).Range.Cells. _
               Shading.BackgroundPatternColorIndex = wdYellow
           End If
            
        Next j
        
    End With
    
  Next i
    
End Sub

マクロ実行前

マクロ実行後

表の1列目をグレーにして、最終列を黄色にしました。

表の行に色付け（カーソルがある行）

以下のWordVBAを実行すると、カーソルがある表の行に色を塗ります。


Sub 表の行に色を付ける()
    
    'カーソルがある表の行を選択
    Selection.SelectRow
    
    '行に色付け（黄色）
    Selection.Shading.BackgroundPatternColor = wdColorYellow
    
End Sub

マクロ実行後

カーソルがある表の行に色付けをしました。

表の行に色付け（任意の行）

以下のWordVBAを実行すると、任意の表の行に色を塗ります。


Sub 表の行に色を付ける()
    
  Dim i As Long
  Dim j As Long
  Dim TblCnt As Long
  Dim TblRowCnt As Long
  Dim CellCnt As Long
    
  'ファイル内にある表をカウント
  TblCnt = ActiveDocument.Tables.Count
    
  '全ての表をループ
  For i = 1 To TblCnt
    
     With ActiveDocument.Tables(i)
        
        TblRowCnt = .Rows.Count
        CellCnt = .Range.Cells.Count
            
        For j = 1 To CellCnt
              
           '1行目の背景色を青に変更
           If .Range.Cells.Item(j).RowIndex = 1 Then
              .Range.Cells.Item(j).Range.Cells. _
               Shading.BackgroundPatternColorIndex = wdBlue
           End If
                
　         '最終行の背景色をピンクに変更
           If .Range.Cells.Item(j).RowIndex = TblRowCnt Then
              .Range.Cells.Item(j).Range.Cells. _
  　　          Shading.BackgroundPatternColorIndex = wdPink
           End If
            
        Next j
        
   End With
    
 Next i
    
End Sub